.TITLE	TTYJ
	.IDENT	/V4.00/
;
; Copyright (c) 1995-1999 by Mentec, Inc., U.S.A.
; All rights reserved
;
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED
; OR COPIED ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
;
;
; 27-JAN-78 PETER WANNHEDEN
;
; PREVIOUSLY MODIFIED BY:
;
;	P. WANNHEDEN
;	C. F. SPITZ
;	D. R. DONCHIN
;
; MODIFICATIONS:
;

	.PSECT	MAP5
;
;+
; CONTROLLER-DEPENDENT ROUTINES FOR DJ-11.
;-
;
;
 
	.IF DF	D$$J11
 
; EQUATED SYMBOLS
;
; DJ-11 REGISTER DEFINITIONS
;
CSR	=	0		;CONTROL AND STATUS REG.
RBUF	=	2		;RECEIVER BUFFER REG.
TCR	=	4		;TRANSMIT CONTROL REG.
TBUF	=	6		;TRANSMITTER BUFFER REG.
;
;
;+
; YJPWUP - POWER UP.
;
; INPUT:
;	REGISTERS R2-R5 STANDARD FOR CONTROLLER-DEPENDENT ROUTINE.
;	U.STS	SET UP FOR LOCAL LINE:
;		US.CRW	0
;		US.DSB	0
;-
;
;

	.IF DF	R$$CON

YJCONL::
YJCPUP::

	.IFF

YJPWUP::TST	R2		;IS THIS LINE ZERO?
	BNE	20$		;N - RETURN

	.IFTF

	MOV	#10,@R3		;CLEAR SILO, UARTS, CONTROLLER
10$:	BIT	#20,@R3		;CLR COMPLETED?
	BNE	10$		;N - WAIT
	BIS	#40501,@R3	;ENABLE INTERRUPTS

	.IFT

YJUONL::
YJUPUP::
YJUOFF::

	.ENDC	;R$$CON

20$:
YJMTIM::RETURN			;RETURN

	.IF DF	R$$CON

YJCOFF::
	MOV	#10,@R3		;CLEAR SILO, UARTS, CONTROLLER
10$:	BIT	#20,@R3		;CLR COMPLETED?
	BNE	10$		;N - LOOP
	RETURN

	.ENDC	;R$$CON

;
;
;+
; INPUT INTERRUPT SERVICE ROUTINE.
;-
;
;
	.ENABL	LSB
;
 
	.IF DF R$$MPL
 
$YJINP::TTSET$	YJ		;;;SAVE R2, R3 AND SET UP:
				;;; R3 = CSR ADDRESS
				;;; R4 = KRB ADDRESS
 
	.IFF	;R$$MPL
 
$DJINP::TTSET$	DJ		;;;SAVE R2,R3 AND SET UP
				;;; R3 = CSR
				;;; R4 = ADDRESS OF UCB LIST
 
	.ENDC	;R$$MPL
 
	CALL	MUXINP		;;;DO COMMON MULTIPLEXER INPUT
				;;;CHARACTER PROCESSING
				;;;MUXINP DISMISSES INTERRUPT IF NO OUTPUT WORK
	BR	10$		;;;XMIT READY - GO DO OUTPUT WORK
;
;
;+
; OUTPUT INTERRUPT SERVICE ROUTINE.
;-
;
;
 
	.IF DF R$$MPL
 
$YJOUT::TTSET$	YJ		;;;SAVE R2, R3 AND SET UP:
				;;; R3 = CSR ADDRESS
				;;; R4 = KRB ADDRESS
 
	.IFF	;R$$MPL
 
$DJOUT::TTSET$	DJ		;;;SAVE R2,R3 AND SET UP
				;;; R3 = CSR
				;;; R4 = ADDRESS OF UCB LIST
 
	.ENDC	;R$$MPL
 
10$:	MOV	R3,-(SP)	;;;
	ADD	#TBUF+1,@SP	;;;POINT TO BYTE CONTAINING
				;;;INTERRUPTING LINE NUMBER (TBUF HIGH BYTE)
	CALL	JZOUT		;;;DO OUTPUT INTERRUPT PROCESSING
				;;;COMMON FOR DJ-11 AND DJ-11
	TST	(SP)+		;;;CLEAN STACK
;
;
;+
; YJABOX - ABORT OUTPUT.
;
; INPUT:
;	REGISTERS R2-R5 STANDARD FOR CONTROLLER-DEPENDENT ROUTINE.
;	U.TOC		0
;	U.TTOC		0
;
; YJSTOX - STOP OUTPUT.
;
; INPUT:
;	REGISTERS R2-R5 STANDARD FOR CONTROLLER-DEPENDENT ROUTINE.
;	S1.CTS		1
;-
;
;
YJABOX::
YJSTOX::RETURN			;;;RETURN
;
	.DSABL	LSB
 
	.ENDC	;D$$J11
 
;
;
	.END